Software > RP Fiber Power > Demo > Nonlinear self-focusing

RP Fiber Power – Simulation and Design Software
for Fiber Optics, Amplifiers and Fiber Lasers

Example Case: Nonlinear Self-focusing in a Fiber

Description of the Model

Here, we investigate details of nonlinear self-focusing in a fiber. First, we calculate how the fundamental mode of a large mode area fiber shrinks as the effect of nonlinear self-focusing.

The mode solver actually ignores nonlinear effects. However, with a few lines of script code we can store the refractive index profile including its nonlinear changes and then recalculate the fiber modes. This is repeated until we get a self-consistent solution:

dr := 0.05 um
defarray I[0, 200 um, dr]
n_f_nl(r) := n_f(r) + n2 * (if r <= r_max then I~[r])
  { nonlinear refractive index profile }
store_I(P) := 
  for r := 0 to 2 * r_co step dr do
    I[r] := P * I_lm(0, 1, lambda, r)
    { ignore index changes outside 2 * r_co, where the intensity is small }
 
CalcNonlinearMode(P) := 
  { Calculate the lowest-order mode with self-focusing for the power P. }
  begin
    var A, A_l;
    A := 0;
    repeat
      A_l := A;
      store_I(P);
      set_n_profile("n_f_nl", r_max);
      A := A_eff_lm(0, 1, lambda);
    until abs(A_l / A - 1) < 1e-6;
  end

We can also numerically simulate the beam propagation, considering the fiber nonlinearity. For that, we need to define a numerical grid and set various other inputs for the beam propagation:

x_max := 30 um { maximum x or y value }
N := 2^5 { number of grid points in x and y direction }
dx := 2 * x_max / N { transverse resolution }
z_max := 30 mm { fiber length }
dz := 100 um { longitudinal resolution }
N_z := z_max / dz { number of z steps }
N_s := 100 { number of sub-steps per dz step }
 
P_11 := 4 MW
A0%(x, y) := sqrt(P_11) * A_lm_xy(1, 1, lambda, x, y)  { initial field }
 
calc
  begin
    bp_set_grid(x_max, N, x_max, N, z_max, N_z, N_s);
    bp_define_channel(lambda);
    bp_set_n('n_f(sqrt(x^2 + y^2))'); { index profile }
    bp_set_loss('10e2 * ((x^2 + y^2) / (20 um)^2)^3');  { simulate loss for cladding modes }
    bp_set_n2('n2');
    bp_set_A0('A0%(x, y)'); { initial amplitude }
    bp_set_interpol(2); { quadratic interpolation }
  end

Results

Figure 1 shows the mode profile for an optical power of 5 MW (not far below the power for catastrophic self-focusing), and the corresponding refractive index profile.

Figure 2 shows the mode area as a function of the optical power. The mode area shrinks dramatically as the critical power is approached.

Figure 3 shows the maximum power as a function of the core radius. For each core radius, one has to calculate the optical power for which the on-axis intensity reaches the damage threshold. Of course, the modes need to be recalculated for each power value.

Initially, the maximum power scales with the core area. For large cores, however, the rise becomes substantially slower, as the mode area is reduced by self-focusing.

Now we investigate what happens if we inject light into the LP₁₁ mode (the first higher-order mode) of the fiber, as calculated without the nonlinearity. For that, we can use numerical beam propagation. Figure 4 shows the result if we inject an optical power of 4 MW, not far below the critical power for self-focusing. Here, the higher-order mode becomes unstable. Even the slightest asymmetry, here resulting from small numerical errors, causes that mode to be transferred into a superposition of the LP₀₁ mode and the LP₁₁ mode after about 10 mm of propagation distance:

We can also show the evolution of optical powers in the guided modes:

It may seem surprising that the total power undergoes some oscillations: how can the power increase at some locations, even though we only have some losses (for cladding modes)? One can understand this as an energy exchange with cladding modes, enabled by the fiber's nonlinearity. Note also that the nonlinear interaction couples light into the cladding mode, which would not happen at low optical powers.

(back to the list of example cases)